iTunes Remote for OperaDS

property my_path : (path to sites folder as text) & "iTunesDSr:images:albums:"
property num_tracks : 0
property last_album : ""

tell application "Finder"
	if exists {((path to preferences folder) as text), "iTunesDSr.plist"} then
		set my_alert to "I see you haven't run iTunesDSr Artwork before." & return & "This will probably take a while. So relax. I'll let you know when I'm done. =)"
		do shell script "defaults write iTunesDSr lastRun '" & (current date) & "'"
	else
		set my_alert to "iTunesDSr Artwork will now export album art added since the last time you ran it. =)"
		do shell script "defaults write iTunesDSr lastRun '" & (current date) & "'"
	end if
end tell

tell application "iTunes"
	if the button returned of (display alert my_alert buttons {"Cancel", "Proceed"}) is "Proceed" then
		set the_albums to album of tracks of library playlist 1
		repeat with i from 1 to count of items in the_albums
			set album_name to item i of the_albums as string
			if album_name is not "" then
				if album_name is not last_album then
					set last_album to album_name
					set the_track to (track 1 whose album is album_name) of library playlist 1
					tell application "Finder"
						set my_x_path to alias my_path
						set album_name to my removeChars(album_name)
						set the_file to (album_name & ".jpg") as string
						if not (exists file the_file of my_x_path) then
							my _make(the_track, album_name)
						end if
					end tell
				end if
			end if
		end repeat
		beep
		display alert "iTunesDSr Artwork finished!" & return & return & num_tracks & " album artworks exported." buttons {"OK"} default button 1
	end if
end tell

on removeChars(this_text)
	set the illegalChars to "\"'\\:?/"
	set the character_list to {}
	repeat with this_char in this_text
		set this_char to the contents of this_char
		if this_char is in the illegalChars then
			set the end of the character_list to ""
		else
			set the end of the character_list to this_char
		end if
	end repeat
	return (the character_list) as string
end removeChars

on _make(the_track, album_name)
	try
		tell application "iTunes"
			set artwork_data to data of artwork 1 of the_track
			if artwork_data is not "" then
				set artwork_image to (open for access my_path & "temp_img" with write permission)
				set eof artwork_image to 512
				write artwork_data to artwork_image starting at 513
				close access artwork_image
				set artwork_data to ""
				tell application "Image Events"
					set this_image to open (my_path & "temp_img") as string
					scale this_image to size 110
					set new_item to (my_path & (album_name) & ".jpg") as string
					save this_image in new_item as JPEG
					close this_image
				end tell
				set num_tracks to num_tracks + 1
			end if
		end tell
	end try
end _make