ZYF

两根相同的钢材料棒，铰接在一起，铰接处施加一个向下的力F，求解钢棒中的应力和铰接点的位移，忽略钢棒的自重。

静态分析，使用Link1单元模拟。 这个问题相当简单，没有太多内容要研究的。

/COM,ANSYS MEDIA REL. 10.0 (05/31/2005) REF. VERIF. MANUAL: REL. 10.0
/VERIFY,VM4
/PREP7
/TITLE, VM4, DEFLECTION OF A HINGED SUPPORT
C***     STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 10, PROB. 2
L=15*12                         ! LENGTH OF BAR IN INCHES
*AFUN,DEG                       ! TRIG FUNCTIONS IN DEGREES 
THETA=30                        ! ANGLE TO BE USED TO CALCULATE A AND B
A=2*L*COS(THETA)                ! CALCULATED X LOCATION - NODE 3
B=L*SIN(THETA)                  ! CALCULATED Y LOCATION - NODE 2
ET,1,LINK1
R,1,.5
MP,EX,1,30E6
N,1
N,2,A/2,-B                      ! X LOCATION = A/2; A AND B AS ABOVE
N,3,A                           
E,1,2
E,2,3
D,1,ALL,,,3,2
F,2,FY,-5000
OUTPR,,1
FINISH
/SOLU    
SOLVE
FINISH
/POST1 
MID_NODE = NODE (A/2,-B,0 )
*GET,DISP,NODE,MID_NODE,U,Y 
LEFT_EL = ENEARN (MID_NODE) 
ETABLE,STRS,LS,1  
*GET,STRSS,ELEM,LEFT_EL,ETAB,STRS 

*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,3
LABEL(1) = 'STRS_psi','DEF_in'
*VFILL,VALUE(1,1),DATA,10000,-0.120
*VFILL,VALUE(1,2),DATA,STRSS,DISP
*VFILL,VALUE(1,3),DATA,ABS(STRSS /10000 ) ,ABS( DISP /0.120 )
/OUT,vm4,vrt
/COM
/COM,------------------- VM4 RESULTS COMPARISON ---------------------
/COM,
/COM,         |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vm4,vrt

Thermally Loaded Support Structure

铜线和钢线悬挂在墙上,下面连接刚性的梁,通过梁施加一个力Q, 同时有一个dT的热载荷。求解铜线和钢线的应力

分析
使用了2D spar单元，下面的三个节点4, 5, 6使用CP进行y方向位移的耦合处理。另外，对于加热造成的热膨胀，设定任意的参考温度70F, 和加载的温度80F（意味着+10F的温度载荷）。结果通过ETABLE进行处理。

INP

finish
/clear
/COM,ANSYS MEDIA REL. 10.0 (05/31/2005) REF. VERIF. MANUAL: REL. 10.0
/VERIFY,VM3
/PREP7
/TITLE, VM3, THERMALLY LOADED SUPPORT STRUCTURE
C***      STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 30, PROB. 9
ANTYPE,STATIC             ! STATIC ANALYSIS
ET,1,LINK1
R,1,.1
MP,EX,1,16E6
MP,ALPX,1,92E-7           ! alpx, alpy, alpz 热膨胀系数？
MP,EX,2,30E6
MP,ALPX,2,70E-7
TREF,70                   ! REFERENCE TEMPERATURE
N,1,-10                   ! DEFINE NODES AND ELEMENTS
N,3,10   
FILL
N,4,-10,-20
N,6,10,-20   
FILL
E,1,4   
E,3,6
MAT,2
E,2,5
CP,1,UY,5,4,6             ! 耦合4, 5, 6三个节点的Y向位移
D,1,ALL,,,3               ! BOUNDARY CONDITIONS AND LOADING
F,5,FY,-4000
BFUNIF,TEMP,80            ! UNIFORM TEMPERATURE (TREF+10)
FINISH
/SOLU    
OUTPR,BASIC,1       
OUTPR,NLOAD,1             
NSUBST,1
SOLVE
FINISH
/POST1                                
STEEL_N  = NODE (,,,)                      ! 选择节点
COPPER_N = NODE (10,0,0)      
STEEL_E = ENEARN (STEEL_N)                 ! 选择单元
COPPER_E = ENEARN (COPPER_N)
ETABLE,STRS_ST,LS,1                        ! LINK1单元的ls,1表示SAXL: Axial stress in the element
ETABLE,STRS_CO,LS,1   
*GET,STRSS_ST,ELEM,STEEL_E,ETAB,STRS_ST  
*GET,STRSS_CO,ELEM,COPPER_E,ETAB,STRS_CO

*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'STRSS_ST','STRSS_CO'
LABEL(1,2) = ' (psi)  ',' (psi)  '
*VFILL,VALUE(1,1),DATA,19695,10152 
*VFILL,VALUE(1,2),DATA,STRSS_ST,STRSS_CO
*VFILL,VALUE(1,3),DATA,ABS(STRSS_ST/19695 ) ,ABS( STRSS_CO/10152 )
/COM
/OUT,vm3,vrt
/COM,------------------- VM3 RESULTS COMPARISON ---------------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.0,'  ',F10.0,'   ',1F5.3)
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vm3,vrt

Statically Indeterminate Reaction Force Analysis

等截面杆两端固定，中间受到相反方向的力的作用，求两端支撑的支反力。

因为物理模型只受到轴向的拉伸，所以可以使用杆单元(spar)来分析，这里使用的是单元link1。另外只对支反力感兴趣，不需要应力应变的结果，所以杆单元的横截面可以给任意值。

需要注意的是此问题是一个静不定问题，在理论力学里面可以使用虚功原理来求解（假设有一个微小位移，然后建立平衡方程进行求解）。

link1 2D两节点杆单元，每节点两个自由度ux, uy，只能承受轴向的拉伸和压缩，可以模拟truss, link, spring

FSUM Sums the nodal force and moment contributions of elements. 对于不受外载荷的节点来说，其对所有相连节点的作用力和力矩的总和必然为0，在此例题中，如果在1、2节点之间多加入一个节点，则此节点的FSUM值等于0

OUTPR 定义结果输出。用于控制输出的内容，对于规模较大的模型，可以使用此命令输出必要的结果，控制结果文件大小。

/COM,ANSYS MEDIA REL. 10.0 (05/31/2005) REF. VERIF. MANUAL: REL. 10.0
/VERIFY,VM1
/PREP7
/TITLE, VM1, STATICALLY INDETERMINATE REACTION FORCE ANALYSIS
C***      STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 26, PROB.10
ANTYPE,STATIC                  ! STATIC ANALYSIS
ET,1,LINK1
R,1,1                          ! CROSS SECTIONAL AREA (ARBITRARY) = 1
MP,EX,1,30E6
N,1
N,2,,4
N,3,,7
N,4,,10
E,1,2                          ! DEFINE ELEMENTS
EGEN,3,1,1
D,1,ALL,,,4,3                  ! BOUNDARY CONDITIONS AND LOADING
F,2,FY,-500
F,3,FY,-1000
FINISH
/SOLU    
OUTPR,BASIC,1                  ! output basic quantities
OUTPR,NLOAD,1                  ! output element nodal loads
SOLVE
FINISH
/POST1
NSEL,S,LOC,Y,10                ! 选取适当节点
FSUM                           ! 获得节点力
*GET,REAC_1,FSUM,,ITEM,FY      ! 赋值给某变量
NSEL,S,LOC,Y,0
FSUM
*GET,REAC_2,FSUM,,ITEM,FY

*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,3
LABEL(1) = 'R1, lb','R2, lb '
*VFILL,VALUE(1,1),DATA,900.0,600.0
*VFILL,VALUE(1,2),DATA,ABS(REAC_1),ABS(REAC_2)
*VFILL,VALUE(1,3),DATA,ABS(REAC_1 / 900) ,ABS( REAC_2 / 600)
/OUT,vm1,vrt
/COM
/COM,------------------- VM1 RESULTS COMPARISON ---------------------
/COM,
/COM,         |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,'   ',F10.1,'  ',F10.1,'   ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vm1,vrt